{
  description = "Dice roller discord bot";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }: let
    pkgs = import nixpkgs { system = "x86_64-linux"; };
    src = pkgs.fetchFromGitHub {
      owner = "Humblemonk";
      repo = "DiceMaiden";
      rev = "9fb207b44e05953c9a27f287ff7d8eb4dcd4978a";
      sha256 = "078i3nfqnin331bhphz4mqi6w5y6xll5v7g7j4qrxzq1xmvrhkaj";
    };
    gems = pkgs.bundlerEnv {
      name = "dicemaiden-env";
      gemfile = "${src}/Gemfile";
      lockfile = ./Gemfile.lock;
      gemset = ./gemset.nix;
      ignoreCollisions = true;
    };
  in rec {
    packages.x86_64-linux = rec {
      default = dicemaiden;
      dicemaiden = pkgs.stdenv.mkDerivation {
        name = "dicemaiden";
        src = src;
        buildInputs = [ gems pkgs.ruby ];
        installPhase = ''
          mkdir -p $out/{bin,share/dicemaiden}
          cp -r * $out/share/dicemaiden
          bin=$out/bin/dicemaiden
          cat > $bin <<EOF
          #!/bin/sh -e
          exec ${gems}/bin/bundle exec ${pkgs.ruby}/bin/ruby $out/share/dicemaiden/dice_maiden.rb "\$@"
          EOF
          chmod +x $bin
        '';
      };
    };
  };
}