dlibrary/flake.nix

{
  description = "DLSite download organizer";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }: let
    pkgs = import nixpkgs {
      system = "x86_64-linux";
      config.allowUnfree = true;
    };
  in {
    packages.x86_64-linux = with pkgs.python3Packages; rec {
      dlsite-async = buildPythonPackage rec {
        pname = "dlsite_async";
        version = "0.5.1";
        src = fetchPypi {
          inherit pname version;
          sha256 = "sha256-xvI13JqW+nOqU4vaeFblbIkiimyEwvGtY+56kRvv2fY=";
        };
        patches = [ ./patches/dlsite-async.patch ];
        pyproject = true;
        nativeBuildInputs = [ pkgs.pdm ];
        propagatedBuildInputs = [
          lxml
          aiohttp
          beautifulsoup4
          pdm-backend
        ];
      };

      dlibrary = buildPythonApplication {
        pname = "dlibrary";
        version = "0.2";
        pyproject = true;
        propagatedBuildInputs = [
          pymupdf
          pillow
          requests
          dlsite-async
          jinja2
          importlib-resources
          setuptools
          libsixel
          (rarfile.override { useUnrar = true; })
          pyuca
        ];
        src = ./.;
      };
      default = dlibrary;
    };
  };
}